AOL File Library: 9,300 to 9,399/9300.zip/AOLDLs/Helper Apps (MAC)/ADD ON_ Internet Config Acces/Internet Config Access .sit/Internet Config Access folder/Source (partial)/InternetConfigAccess.mod

Text File | 1995-02-09 | 62KB | 2,781 lines

MODULE InternetConfigAccess;
(*
    Internet Config Access -- a utility to give
    access via AppleScript to the Internet Config database.

    Start of development by LDO 1995 January 19.
    First working version 1995 February 3.
    Last modified 1995 February 9.
*)

    IMPORT
        SYSTEM;
    FROM SYSTEM IMPORT
        ADDRESS,
        ADR,
        CAST;
    IMPORT
        Types;
    FROM Types IMPORT
        noErr,
        IORefNum,
        OSErr,
        ResID,
        ShortInt,
        Str255,
        StringHandle,
        StringPtr;
    IMPORT
        Errors;
    IMPORT
        Memory;
    FROM Memory IMPORT
        HLock,
        HUnlock;
    IMPORT
        Files;
    IMPORT
        Resources;
    FROM Resources IMPORT
        CurResFile,
        UseResFile;
    FROM TextUtils IMPORT
        GetIndString,
        NumToString;
    IMPORT
        QuickDraw;
    FROM QuickDraw IMPORT
        GrafPort;
    IMPORT
        Components;
    FROM Components IMPORT
        ComponentInstance;
    IMPORT
        Menus;
    IMPORT
        Dialogs;
    FROM Dialogs IMPORT
        ParamText;
    IMPORT
        AppleEvents;
    FROM AppleEvents IMPORT
        AEDesc,
        AEEventClass,
        AEEventID,
        AESendMode,
        AppleEvent,
        AEInteractWithUser,
        AESend;
    IMPORT
        AEObjects;
    FROM AEPackObject IMPORT
        CreateObjSpecifier;
    IMPORT
        AERegistry;
    IMPORT
        BitManipulation;
    IMPORT
        Useful;
    FROM Useful IMPORT
        DAStrings,
        CurrentA6;
    IMPORT
        Compatibility;
    FROM Compatibility IMPORT
        AppleEventsPresent;
    IMPORT
        CountedStrings;
    FROM CountedStrings IMPORT
        CopyCounted,
        MakeCounted;
    IMPORT
        HLUseful;
    FROM HLUseful IMPORT
        StringExpanders,
        DisplayMessageDialog,
        ExpandString;
    IMPORT
        AEUseful;
    FROM AEUseful IMPORT
        DisposeAEDesc,
        InitAEDesc,
        MakeStringDesc,
        PutStringParam;
    IMPORT
        AEObjectUseful;
    IMPORT
        CommandHandler;
    FROM CommandHandler IMPORT
        Command,
        StateVariable,
        GetStateVariableState;
    IMPORT
        EventHandler;
    IMPORT
        MenuHandler;
    IMPORT
        ICTypes;
    IMPORT
        ICCAPI;

(*
    Global data
*)

    CONST
        MySignature = 0494E5853H (* 'INXS' *);

    CONST
      (* custom class codes *)
        ClassConfigEntry = 049434145H (* 'ICAE' *);
    CONST
      (* custom property IDs *)
        SeedPropertyID = 053656564H (* 'Seed' *);
        ChangesAllowedPropertyID = 052645772H (* 'RdWr' *);
        ScramblingAllowedPropertyID = 03F505744H (* '?PWD' *);
        ValuePropertyID = 056414C55H (* 'VALU' *);
        LockedPropertyID = 04C434B44H (* 'LCKD' *);
        VolatilePropertyID = 0564F4C41H (* 'VOLA' *);

    CONST
      (* custom type codes *)
        TypeBlob = 0424C4F42H (* 'BLOB' *); (* an arbitrary block of data *)
        TypeEntryAttributes = 041545452H (* 'ATTR' *);

    CONST
      (* custom token field types *)
        EntryNameFieldID = 04E414D45H (* 'NAME' *);
        EntrySizeFieldID = 053495A45H (* 'SIZE' *);
        EntryAttributesFieldID = 041545452H (* 'ATTR' *);

    CONST
      (* custom event codes *)
        ScramblePasswordEventID = 03E505744H (* '>PWD' *);
        UnscramblePasswordEventID = 03C505744H (* '<PWD' *);
        ConvertFromPStringBlobID = 03C535452H (* '<STR' *);
        ConvertToPStringBlobID = 03E535452H (* '>STR' *);
        ConvertFromTextBlobID = 03C545854H (* '<TXT' *);
        ConvertToTextBlobID = 03E545854H (* '>TXT' *);
        ConvertFromStringListBlobID = 03C535423H (* '<ST#' *);
        ConvertToStringListBlobID = 03E535423H (* '>ST#' *);

    CONST
        MiscStringsID = 128;
      (* indexes into 'STR#' ID MiscStringsID: *)
        OKStringIndex = 1;
        CancelStringIndex = 2;

    CONST
        MessageStringsID = 129;
      (* indexes into 'STR#' ID MessageStringsID: *)
        AboutMsgIndex = 1;
        ErrorEncounteredStringIndex = 2;
        NeedAppleScriptIndex = 3;
        NeedInternetConfigIndex = 4;

    VAR
        AppResFile : IORefNum;
        DefaultPort : GrafPort;
        ChangesAllowed, ScramblingAllowed : StateVariable;
        Quitting : BOOLEAN;
        CurrentReply : AEDesc;
        InternetConfig : ComponentInstance;
        Err : OSErr;

    VAR
        QuitCommand : Command;

(*
    Useful stuff
*)

    PROCEDURE PermsToUse() : ICTypes.ICPerm;
      (* returns the appropriate permissions to use for accessing
        the configuration database. *)

        VAR
            ThePerms : ICTypes.ICPerm;

    BEGIN
        IF GetStateVariableState(ChangesAllowed) <> 0 THEN
            ThePerms := ICTypes.icReadWritePerm
        ELSE
            ThePerms := ICTypes.icReadOnlyPerm
        END (*IF*);
        RETURN
            ThePerms
    END PermsToUse;

    PROCEDURE CreateSelfEvent
      (
        TheAEEventClass : AEEventClass;
        TheAEEventID : AEEventID;
        VAR Result : AppleEvent
      );
      (* creates an AppleEvent to be sent to myself. *)

    BEGIN
        AEUseful.CreateSelfEvent
          (
            (*EventClass :=*) TheAEEventClass,
            (*EventID :=*) TheAEEventID,
            (*ReturnID :=*) AppleEvents.kAutoGenerateReturnID,
            (*TransactionID :=*) AppleEvents.kAnyTransactionID,
            (*@Result :=*) Result,
            (*@Err :=*) Err
          )
    END CreateSelfEvent;

    PROCEDURE SendEvent
      (
        VAR TheEvent : AppleEvent;
        CanInteract : BOOLEAN
      );
      (* sends the specified event to its target. *)

        VAR
            SendMode : AESendMode;
            Reply : AppleEvent;

    BEGIN
        InitAEDesc(Reply);
        SendMode := AppleEvents.kAENoReply;
        IF CanInteract THEN
            SendMode :=
                    SendMode
                +
                    AppleEvents.kAECanInteract
                +
                    AppleEvents.kAECanSwitchLayer
        ELSE
            SendMode := SendMode + AppleEvents.kAENeverInteract
        END (*IF*);
        Err := AESend
          (
            (*@theAppleEvent :=*) TheEvent,
            (*@reply :=*) Reply,
            (*sendMode :=*) SendMode,
            (*sendPriority :=*) AppleEvents.kAENormalPriority,
            (*timeOutInTicks :=*) AppleEvents.kAEDefaultTimeout,
            (*idleProc :=*) AppleEvents.NoIdleFunction,
            (*filterProc :=*) AppleEvents.NoEventFilterProc
          );
        DisposeAEDesc(Reply)
    END SendEvent;

    PROCEDURE SendMyselfSimpleEvent
      (
        TheAEEventClass : AEEventClass;
        TheAEEventID : AEEventID
      );
      (* sends myself a parameterless event with the
        specified class and ID. *)

        VAR
            TheEvent : AppleEvent;

    BEGIN
        InitAEDesc(TheEvent);
        LOOP (*once*)
            CreateSelfEvent
              (
                (*TheAEEventClass :=*) TheAEEventClass,
                (*TheAEEventID :=*) TheAEEventID,
                (*@Result :=*) TheEvent
              );
            IF Err <> noErr THEN
                EXIT
            END (*IF*);
            SendEvent(TheEvent, TRUE);
          (* all done *)
            EXIT
        END (*LOOP*);
        DisposeAEDesc(TheEvent)
    END SendMyselfSimpleEvent;

    PROCEDURE CreateEntryDescriptor
      (
        VAR EntryName : ARRAY OF CHAR;
        VAR ObjectDescriptor : AEDesc
      );
      (* creates an object descriptor for the configuration entry
        with the specified name. *)

        VAR
            NullDescriptor, NameDescriptor : AEDesc;

    BEGIN
        InitAEDesc(NullDescriptor);
        InitAEDesc(NameDescriptor);
        LOOP (*once*)
            MakeStringDesc
              (
                (*@TheString :=*) EntryName,
                (*@TheDesc :=*) NameDescriptor,
                (*@Err :=*) Err
              );
            IF Err <> noErr THEN
                EXIT
            END (*IF*);
            Err := CreateObjSpecifier
              (
                (*desiredClass :=*) ClassConfigEntry,
                (*@theContainer :=*) NullDescriptor,
                (*keyForm :=*) AEObjects.formName,
                (*@keyData :=*) NameDescriptor,
                (*disposeInputs :=*) FALSE,
                (*@objSpecifier :=*) ObjectDescriptor
              );
            IF Err <> noErr THEN
                EXIT
            END (*IF*);
         (* all done *)
            EXIT
        END (*LOOP*);
        DisposeAEDesc(NameDescriptor)
    END CreateEntryDescriptor;

(*
    Message display
*)

    PROCEDURE CanInteract() : BOOLEAN;
      (* is interaction with the user currently allowed or not. *)

        VAR
            Err : OSErr;

    BEGIN
        IF AppleEventsPresent() THEN (* could be called when displaying error message about lack of AppleEvents *)
            Err := AEInteractWithUser
              (
                (*timeOutInTicks :=*) AppleEvents.kAEDefaultTimeout,
                (*nmReqPtr :=*) NIL,
                (*idleProc :=*) AppleEvents.NoIdleFunction
              )
        ELSE
            Err := noErr
        END (*IF*);
        RETURN
            Err = noErr
    END CanInteract;

    PROCEDURE DisplayMessageIndex
      (
        MessageIndex : CARDINAL;
        IconID : ResID
      );
      (* displays the appropriate message string from 'STR#'
        ID MessageStringsID, accompanied by the specified icon. *)

        VAR
            PreviousResFile : IORefNum;
            MessageTemplate, MessageString, OKString : Str255;
            ExpansionTemp : Str255;
            ButtonHit : ShortInt;

        PROCEDURE SubstituteParamStrings
          (
            EscapeCode : CHAR;
            VAR Expansion : StringPtr
          );
          (* substitutes dialog parameter strings into message text. *)

            VAR
                ThisString : StringHandle;

        BEGIN
            CASE EscapeCode OF
            | '0', '1', '2', '3':
                ThisString := DAStrings[ORD(EscapeCode) - ORD('0')]
            ELSE
                ThisString := NIL
            END (*CASE*);
            IF ThisString <> NIL THEN
                HLock(ThisString);
                CopyCounted(ThisString^, ExpansionTemp);
                HUnlock(ThisString);
                Expansion := ADR(ExpansionTemp)
            END (*IF*)
        END SubstituteParamStrings;

    BEGIN (*DisplayMessageIndex*)
        PreviousResFile := CurResFile();
        UseResFile(AppResFile);
        IF CanInteract() THEN
            GetIndString(OKString, MiscStringsID, OKStringIndex);
            GetIndString(MessageTemplate, MessageStringsID, MessageIndex);
            DisplayMessageDialog
              (
                (*MessageString :=*) ADR(MessageTemplate),
                (*SubstituteParamText :=*) TRUE,
                (*IconID :=*) IconID,
                (*Button1String :=*) ADR(OKString),
                (*Button2String :=*) NIL,
                (*Button3String :=*) NIL,
                (*Filter :=*) Dialogs.noModalFilterProc,
                (*@ButtonHit :=*) ButtonHit
              )
        ELSIF CurrentReply.dataHandle <> NIL THEN
            ExpandString
              (
                (*Source :=*) ADR(MessageTemplate),
                (*@Destination :=*) MessageString,
                (*Escape :=*) HLUseful.StandardEscape,
                (*International :=*) TRUE,
                (*Expand :=*) CAST(StringExpanders, ADR(SubstituteParamStrings)),
                (*ExpanderArg :=*) CurrentA6()
              );
            PutStringParam
              (
                (*@TheAppleEvent :=*) CurrentReply,
                (*Keyword :=*) AppleEvents.keyErrorString,
                (*@TheString :=*) MessageString,
                (*@Err :=*) Err
              )
        END (*IF*);
        UseResFile(PreviousResFile)
    END DisplayMessageIndex;

    PROCEDURE DisplayErrorMessageIndex
      (
        MessageIndex : CARDINAL
      );
      (* displays the appropriate message string from 'STR#'
        ID MessageStringsID, as an error message. *)

    BEGIN
        DisplayMessageIndex
          (
            (*MessageIndex :=*) MessageIndex,
            (*IconID :=*) Dialogs.stopIcon
          )
    END DisplayErrorMessageIndex;

    PROCEDURE OSError
      (
        DoingWhat : ARRAY OF CHAR
      ) : BOOLEAN;
      (* reports an error message iff Err is nonzero, returning
        true if so. *)

        VAR
            Param0, Param1 : Str255;
            NullString : CHAR;
            GotError : BOOLEAN;

    BEGIN
        GotError := Err <> noErr;
        IF GotError THEN
            NumToString(Err, Param0);
            MakeCounted(DoingWhat, Param1);
            NullString := 0C;
            ParamText(ADR(Param0), ADR(Param1), ADR(NullString), ADR(NullString));
            DisplayErrorMessageIndex(ErrorEncounteredStringIndex)
        END (*IF*);
        RETURN
            GotError
    END OSError;

(*
    AppleEvent handling
*)

    MODULE AEHandling;

        FROM SYSTEM IMPORT
            ADDRESS,
            ADR,
            CAST,
            SAVEREGS;
        FROM Types IMPORT
            noErr,
            Byte,
            HandleState,
            IORefNum,
            OSErr,
            RefConType,
            ShortCard,
            Size,
            Str255,
            StringPtr;
        IMPORT
            Errors;
        FROM Memory IMPORT
            BlockMoveData,
            GetHandleSize,
            HLock,
            HSetState,
            HUnlock,
            MemError,
            NewHandle,
            SetHandleSize;
        FROM Resources IMPORT
            CurResFile,
            Get1Resource,
            UseResFile;
        FROM Dialogs IMPORT
            ParamText;
        IMPORT
            AppleEvents;
        FROM AppleEvents IMPORT
            AEDesc,
            AEDescList,
            AEEventClass,
            AEEventID,
            AEHandlerProc,
            AEKeyword,
            AERecord,
            AppleEvent,
            DescCoercionHandler,
            DescType,
            PtrCoercionHandler,
            AECreateDesc,
            AEGetKeyDesc,
            AEInstallDescCoercionHandler,
            AEInstallEventHandler,
            AEInstallPtrCoercionHandler,
            AEPutParamDesc,
            AEPutParamPtr,
            AEPutPtr;
        IMPORT
            AERegistry;
        IMPORT
            AEObjects;
        FROM AEObjects IMPORT
            AccessorProc,
            CountProc,
            AEInstallObjectAccessor,
            AEObjectInit,
            AESetObjectCallbacks;
        FROM BitManipulation IMPORT
            BXorBU;
        IMPORT
            Useful;
        FROM Useful IMPORT
            CurrentA6,
            GetByte,
            IgnoreComponentResult,
            NoPurgeHandle,
            SetByte,
            SetWord,
            TraverseStringList;
        FROM CountedStrings IMPORT
            AppendCharBlock;
        FROM HLUseful IMPORT
            NoCleanupList,
            GetShortVersionString;
        FROM AEUseful IMPORT
            AEListAction,
            CoerceToBlock,
            CoerceToString,
            DisposeAEDesc,
            DisposeAEToken,
            GetBoolArg,
            GetStringArg,
            InitAEDesc,
            NewAEList,
            TraverseAEList;
        IMPORT
            AEObjectUseful;
        FROM AEObjectUseful IMPORT
            AEToken,
            AppToken,
            AddAccessorProc,
            AddCompareProc,
            AddCountProc,
            AddAEHandlerProc,
            AddElementCreatorRoutine,
            AddPropertyAccessorProc,
            CreateAEToken,
            GetCurrentToken,
            GetDataArg,
            GetPrivateDataField,
            SetDataBlockField,
            SetDataDescriptorField,
            SetDataField,
            SetDataSizeField,
            SetDataTypeField,
            SetGetDataRoutineField,
            SetObjectDescriptor,
            SetPrivateDataField,
            SetSetDataRoutineField;
        FROM CommandHandler IMPORT
            StateVariable,
            GetStateVariableState;
        IMPORT
            ICTypes;
        FROM ICTypes IMPORT
            ICAttr;
        FROM ICCAPI IMPORT
            ICBegin,
            ICCountPref,
            ICDeletePref,
            ICEnd,
            ICGetIndPref,
            ICGetPref,
            ICGetSeed,
            ICSetPref;
        IMPORT
            AboutMsgIndex,
            ChangesAllowedPropertyID,
            ClassConfigEntry,
            ConvertFromPStringBlobID,
            ConvertFromStringListBlobID,
            ConvertFromTextBlobID,
            ConvertToPStringBlobID,
            ConvertToStringListBlobID,
            ConvertToTextBlobID,
            EntryAttributesFieldID,
            EntryNameFieldID,
            EntrySizeFieldID,
            LockedPropertyID,
            MySignature,
            ScramblePasswordEventID,
            ScramblingAllowedPropertyID,
            SeedPropertyID,
            TypeBlob,
            TypeEntryAttributes,
            UnscramblePasswordEventID,
            ValuePropertyID,
            VolatilePropertyID,
            AppResFile,
            ChangesAllowed,
            Err,
            InternetConfig,
            Quitting,
            ScramblingAllowed,
            CreateEntryDescriptor,
            DisplayMessageIndex;
        EXPORT
            InitAEHandling;

        PROCEDURE HandleOpenApplicationEvent
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* handles an "open application" event. *)

        BEGIN
            SAVEREGS;
          (* nothing to do *)
            RETURN
                noErr
        END HandleOpenApplicationEvent;

        PROCEDURE HandleQuitEvent
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* handles a request to quit the application. *)

        BEGIN
            SAVEREGS;
            Quitting := TRUE;
            RETURN
                noErr
        END HandleQuitEvent;

        PROCEDURE HandleAboutEvent
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* handles a request to display my about box. *)

            VAR
                VersionStr : Str255;
                NullString : CHAR;

        BEGIN
            SAVEREGS;
            GetShortVersionString(1, VersionStr);
            NullString := 0C;
            ParamText
              (
                ADR(VersionStr),
                ADR(NullString),
                ADR(NullString),
                ADR(NullString)
              );
            DisplayMessageIndex(AboutMsgIndex, 128);
            RETURN
                noErr
        END HandleAboutEvent;

        PROCEDURE HandleScramblePassword
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* handles scrambling/unscrambling of passwords. *)

            VAR
                TheData : AEDesc;
                DataSize, ThisOffset : Size;
                ThisPtr : ADDRESS;

        BEGIN
            SAVEREGS;
            InitAEDesc(TheData);
            LOOP (*once*)
                IF GetStateVariableState(ScramblingAllowed) = 0 THEN
                    Err := AppleEvents.errAEEventNotHandled;
                    EXIT
                END (*IF*);
                GetDataArg
                  (
                    (*@TheAppleEvent :=*) TheAppleEvent,
                    (*ArgKeyword :=*) AppleEvents.keyDirectObject,
                    (*DesiredType :=*) AppleEvents.typeChar,
                    (*@TheData :=*) TheData,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                DataSize := GetHandleSize(TheData.dataHandle);
                ThisOffset := 0;
                LOOP
                  (* apply symmetrical scrambling/unscrambling algorithm *)
                    IF ThisOffset = DataSize THEN
                        EXIT
                    END (*IF*);
                    ThisPtr := TheData.dataHandle^ + ThisOffset;
                    INC(ThisOffset);
                    SetByte
                      (
                        (*Val :=*) BXorBU
                          (
                            CAST(Byte, GetByte(ThisPtr)),
                            CAST(Byte, ThisOffset + 055H)
                          ),
                        (*Dst :=*) ThisPtr
                      )
                END (*LOOP*);
                Err := AEPutParamDesc
                  (
                    (*@theAppleEvent :=*) Reply,
                    (*theAEKeyword :=*) AppleEvents.keyDirectObject,
                    (*@theAEDesc :=*) TheData
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            DisposeAEDesc(TheData);
            RETURN
                Err
        END HandleScramblePassword;

        PROCEDURE ConvertFromPStringBlob
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* treats a blob as a Pascal string and converts it to text. *)

            VAR
                SrcData, DstData : AEDesc;
                StringLength : CARDINAL;

        BEGIN
            SAVEREGS;
            InitAEDesc(SrcData);
            InitAEDesc(DstData);
            LOOP (*once*)
                GetDataArg
                  (
                    (*@TheAppleEvent :=*) TheAppleEvent,
                    (*ArgKeyword :=*) AppleEvents.keyDirectObject,
                    (*DesiredType :=*) TypeBlob,
                    (*@TheData :=*) SrcData,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                HLock(SrcData.dataHandle);
                StringLength := CAST(CARDINAL, SrcData.dataHandle^^);
                Err := AECreateDesc
                  (
                    (*typeCode :=*) AppleEvents.typeChar,
                    (*dataPtr :=*) SrcData.dataHandle^ + 1,
                    (*dataSize :=*) StringLength,
                    (*@result :=*) DstData
                  );
                HUnlock(SrcData.dataHandle);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                Err := AEPutParamDesc
                  (
                    (*@theAppleEvent :=*) Reply,
                    (*theAEKeyword :=*) AppleEvents.keyDirectObject,
                    (*@theAEDesc :=*) DstData
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            DisposeAEDesc(SrcData);
            DisposeAEDesc(DstData);
            RETURN
                Err
        END ConvertFromPStringBlob;

        PROCEDURE ConvertToPStringBlob
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* converts text to a blob as a Pascal string. *)

            VAR
                SrcData : AEDesc;
                ActualType : DescType;
                SrcStr : Str255;

        BEGIN
            SAVEREGS;
            InitAEDesc(SrcData);
            LOOP (*once*)
                GetDataArg
                  (
                    (*@TheAppleEvent :=*) TheAppleEvent,
                    (*ArgKeyword :=*) AppleEvents.keyDirectObject,
                    (*DesiredType :=*) AppleEvents.typeChar,
                    (*@TheData :=*) SrcData,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                CoerceToString
                  (
                    (*@TheDesc :=*) SrcData,
                    (*@Result :=*) SrcStr,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                Err := AEPutParamPtr
                  (
                    (*@theAppleEvent :=*) Reply,
                    (*theAEKeyword :=*) AppleEvents.keyDirectObject,
                    (*typeCode :=*) TypeBlob,
                    (*dataPtr :=*) ADR(SrcStr),
                    (*dataSize :=*) ORD(SrcStr[0]) + 1
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            DisposeAEDesc(SrcData);
            RETURN
                Err
        END ConvertToPStringBlob;

        PROCEDURE ConvertFromTextBlob
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* converts a blob to text. *)

            VAR
                TheData : AEDesc;

        BEGIN
            SAVEREGS;
            InitAEDesc(TheData);
            LOOP (*once*)
                GetDataArg
                  (
                    (*@TheAppleEvent :=*) TheAppleEvent,
                    (*ArgKeyword :=*) AppleEvents.keyDirectObject,
                    (*DesiredType :=*) TypeBlob,
                    (*@TheData :=*) TheData,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                TheData.descriptorType := AppleEvents.typeChar;
                Err := AEPutParamDesc
                  (
                    (*@theAppleEvent :=*) Reply,
                    (*theAEKeyword :=*) AppleEvents.keyDirectObject,
                    (*@theAEDesc :=*) TheData
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            DisposeAEDesc(TheData);
            RETURN
                Err
        END ConvertFromTextBlob;

        PROCEDURE ConvertToTextBlob
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* converts text to a blob. *)

            VAR
                TheData : AEDesc;

        BEGIN
            SAVEREGS;
            InitAEDesc(TheData);
            LOOP (*once*)
                GetDataArg
                  (
                    (*@TheAppleEvent :=*) TheAppleEvent,
                    (*ArgKeyword :=*) AppleEvents.keyDirectObject,
                    (*DesiredType :=*) AppleEvents.typeChar,
                    (*@TheData :=*) TheData,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                TheData.descriptorType := TypeBlob;
                Err := AEPutParamDesc
                  (
                    (*@theAppleEvent :=*) Reply,
                    (*theAEKeyword :=*) AppleEvents.keyDirectObject,
                    (*@theAEDesc :=*) TheData
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            DisposeAEDesc(TheData);
            RETURN
                Err
        END ConvertToTextBlob;

        PROCEDURE ConvertFromStringListBlob
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* converts a STR#-format blob to a list of text strings. *)

            VAR
                SrcData : AEDesc;
                DstData : AEDescList;

            PROCEDURE AnotherString
              (
                ThisString : StringPtr;
                StringIndex : CARDINAL;
                VAR KeepGoing : BOOLEAN
              );
              (* action routine to add another string to the result list. *)

            BEGIN
                Err := AEPutPtr
                  (
                    (*@theAEDescList :=*) DstData,
                    (*index :=*) 0,
                    (*typeCode :=*) AppleEvents.typeChar,
                    (*dataPtr :=*) ADR(ThisString^[1]),
                    (*dataSize :=*) ORD(ThisString^[0])
                  );
                IF Err <> noErr THEN
                    KeepGoing := FALSE
                END (*IF*)
            END AnotherString;

        BEGIN (*ConvertFromStringListBlob*)
            SAVEREGS;
            InitAEDesc(SrcData);
            InitAEDesc(DstData);
            LOOP (*once*)
                GetDataArg
                  (
                    (*@TheAppleEvent :=*) TheAppleEvent,
                    (*ArgKeyword :=*) AppleEvents.keyDirectObject,
                    (*DesiredType :=*) TypeBlob,
                    (*@TheData :=*) SrcData,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                NewAEList(DstData, Err);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                HLock(SrcData.dataHandle);
                TraverseStringList
                  (
                    (*TheStringList :=*) SrcData.dataHandle,
                    (*Action :=*) CAST(Useful.StringListActions, ADR(AnotherString)),
                    (*ActionArg :=*) CurrentA6()
                  );
                HUnlock(SrcData.dataHandle);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                Err := AEPutParamDesc
                  (
                    (*@theAppleEvent :=*) Reply,
                    (*theAEKeyword :=*) AppleEvents.keyDirectObject,
                    (*@theAEDesc :=*) DstData
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            DisposeAEDesc(SrcData);
            DisposeAEDesc(DstData);
            RETURN
                Err
        END ConvertFromStringListBlob;

        PROCEDURE ConvertToStringListBlob
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* converts a list of text strings to a STR#-format blob. *)

            CONST
                GrowIncrement = 256;
            VAR
                SrcData : AEDescList;
                DstData : AEDesc;
                DstDataOffset, DstDataSize : LONGCARD;
                NrStrings : ShortCard;

            PROCEDURE AnotherString
              (
                VAR TheElement : AEDesc;
                ElementIndex : LONGINT;
                ElementKeyword : AEKeyword;
                VAR KeepGoing : BOOLEAN
              );
              (* action routine to add another string to the result list. *)

                VAR
                    ThisStr : Str255;
                    StringLength, NewDataSize : LONGCARD;

            BEGIN
                LOOP (*once*)
                    ThisStr[0] := 0C;
                    HLock(TheElement.dataHandle);
                    AppendCharBlock
                      (
                        (*Src :=*) TheElement.dataHandle^,
                        (*Length :=*) GetHandleSize(TheElement.dataHandle),
                        (*@Dst :=*) ThisStr
                      );
                    HUnlock(TheElement.dataHandle);
                    StringLength := ORD(ThisStr[0]) + 1;
                    IF DstDataOffset + StringLength > DstDataSize THEN
                        NewDataSize := DstDataSize + GrowIncrement;
                        SetHandleSize(DstData.dataHandle, NewDataSize);
                        IF Err <> noErr THEN
                            EXIT
                        END (*IF*);
                        DstDataSize := NewDataSize
                    END (*IF*);
                    INC(NrStrings);
                    BlockMoveData
                      (
                        (*sourcePtr :=*) ADR(ThisStr),
                        (*destPtr :=*) DstData.dataHandle^ + DstDataOffset,
                        (*byteCount :=*) StringLength
                      );
                    DstDataOffset := DstDataOffset + StringLength;
                  (* all done *)
                    EXIT
                END (*LOOP*);
                IF Err <> noErr THEN
                    KeepGoing := FALSE
                END (*IF*)
            END AnotherString;

        BEGIN (*ConvertToStringListBlob*)
            SAVEREGS;
            InitAEDesc(SrcData);
            InitAEDesc(DstData);
            LOOP (*once*)
                GetDataArg
                  (
                    (*@TheAppleEvent :=*) TheAppleEvent,
                    (*ArgKeyword :=*) AppleEvents.keyDirectObject,
                    (*DesiredType :=*) AppleEvents.typeAEList,
                    (*@TheData :=*) SrcData,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                DstDataSize := GrowIncrement;
                DstData.dataHandle := NewHandle(DstDataSize);
                Err := MemError();
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                DstDataOffset := SIZE(ShortCard);
                NrStrings := 0;
                TraverseAEList
                  (
                    (*@TheList :=*) SrcData,
                    (*Action :=*) CAST(AEListAction, ADR(AnotherString)),
                    (*ActionArg :=*) CurrentA6(),
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetWord(NrStrings, DstData.dataHandle^);
                SetHandleSize(DstData.dataHandle, DstDataOffset);
                DstData.descriptorType := TypeBlob;
                Err := AEPutParamDesc
                  (
                    (*@theAppleEvent :=*) Reply,
                    (*theAEKeyword :=*) AppleEvents.keyDirectObject,
                    (*@theAEDesc :=*) DstData
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            DisposeAEDesc(SrcData);
            DisposeAEDesc(DstData);
            RETURN
                Err
        END ConvertToStringListBlob;

        PROCEDURE AccessVersionProperty
          (
            DesiredClass : DescType;
            VAR Container : AEDesc;
            ContainerClass : DescType;
            KeyForm : DescType;
            VAR KeyData : AEDesc;
            VAR TheToken : AEDesc;
            TheRefCon : RefConType
          ) : OSErr;
          (* returns a token for the application's version property (read-only). *)

            VAR
                PreviousResFile : IORefNum;
                VersionDesc : AEDesc;
                VersionState : HandleState;

        BEGIN
            PreviousResFile := CurResFile();
            VersionDesc.dataHandle := NIL;
            LOOP (*once*)
                UseResFile(AppResFile);
                VersionDesc.dataHandle := Get1Resource(Useful.VersionResourceType, 1);
                IF VersionDesc.dataHandle = NIL THEN
                    Err := AppleEvents.errAEEventNotHandled;
                    EXIT
                END (*IF*);
                NoPurgeHandle(VersionDesc.dataHandle, VersionState);
                VersionDesc.descriptorType := AERegistry.typeVersion;
                CreateAEToken
                  (
                    (*TheCleanup :=*) NoCleanupList,
                    (*@Result :=*) TheToken,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetDataDescriptorField
                  (
                    (*@TheToken :=*) TheToken,
                    (*@TheData :=*) VersionDesc,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            IF VersionDesc.dataHandle <> NIL THEN
                HSetState(VersionDesc.dataHandle, VersionState)
            END (*IF*);
            UseResFile(PreviousResFile);
            RETURN
                Err
        END AccessVersionProperty;

        PROCEDURE AccessSeedProperty
          (
            DesiredClass : DescType;
            VAR Container : AEDesc;
            ContainerClass : DescType;
            KeyForm : DescType;
            VAR KeyData : AEDesc;
            VAR TheToken : AEDesc;
            TheRefCon : RefConType
          ) : OSErr;
          (* returns a token for the application's seed
            property (read-only). *)

            VAR
                TheSeed : LONGCARD;

        BEGIN
            LOOP (*once*)
                CreateAEToken
                  (
                    (*TheCleanup :=*) NoCleanupList,
                    (*@Result :=*) TheToken,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                Err := ICGetSeed(InternetConfig, TheSeed);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*DataType :=*) AppleEvents.typeLongInteger,
                    (*@Src :=*) TheSeed,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            RETURN
                Err
        END AccessSeedProperty;

        PROCEDURE AccessGlobalStateProperty
          (
            DesiredClass : DescType;
            VAR Container : AEDesc;
            ContainerClass : DescType;
            KeyForm : DescType;
            VAR KeyData : AEDesc;
            VAR TheToken : AEDesc;
            VAR TheGlobal : StateVariable
          ) : OSErr;
          (* returns a token for a global boolean property which is read-only. *)

            VAR
                BooleanValue : BOOLEAN;

        BEGIN
            LOOP (*once*)
                CreateAEToken
                  (
                    (*TheCleanup :=*) NoCleanupList,
                    (*@Result :=*) TheToken,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                BooleanValue := GetStateVariableState(TheGlobal) <> 0;
                SetDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*DataType :=*) AppleEvents.typeBoolean,
                    (*@Src :=*) BooleanValue,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            RETURN
                Err
        END AccessGlobalStateProperty;

        PROCEDURE AccessConfigEntryName
          (
            DesiredClass : DescType;
            VAR Container : AEDesc;
            ContainerClass : DescType;
            KeyForm : DescType;
            VAR KeyData : AEDesc;
            VAR TheToken : AEDesc;
            TheRefCon : RefConType
          ) : OSErr;
          (* returns a token for the name property property of a configuration entry. *)

            VAR
                EntryName : Str255;

        BEGIN
            InitAEDesc(TheToken);
            LOOP (*once*)
                GetPrivateDataField
                  (
                    (*@TheToken :=*) Container,
                    (*FieldID :=*) EntryNameFieldID,
                    (*DesiredType :=*) TypeBlob,
                    (*@Dst :=*) EntryName,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                CreateAEToken
                  (
                    (*TheCleanup :=*) NoCleanupList,
                    (*@Result :=*) TheToken,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetDataBlockField
                  (
                    (*@TheToken :=*) TheToken,
                    (*DataType :=*) AppleEvents.typeChar,
                    (*Src :=*) ADR(EntryName[1]),
                    (*Length :=*) ORD(EntryName[0]),
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                AddCompareProc
                  (
                    (*@TheToken :=*) TheToken,
                    (*Operator :=*) AppleEvents.typeWildCard,
                    (*Compare :=*) AEObjectUseful.CompareStrings,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            RETURN
                Err
        END AccessConfigEntryName;

        PROCEDURE GetConfigEntryValue
          (
            VAR TheToken : AEToken;
            Dest : ADDRESS;
            DestType : DescType;
            RefCon : RefConType
          ) : OSErr;
          (* get-data routine to return the current value of a
            configuration entry. *)

            VAR
                EntryName : Str255;
                EntrySize : Size;
                EntryAttributes : ICAttr;

        BEGIN
            LOOP (*once*)
                GetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntryNameFieldID,
                    (*DesiredType :=*) TypeBlob,
                    (*@Dst :=*) EntryName,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                GetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntrySizeFieldID,
                    (*DesiredType :=*) AppleEvents.typeLongInteger,
                    (*@Dst :=*) EntrySize,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                Err := ICBegin(InternetConfig, ICTypes.icReadOnlyPerm);
                IF Err = noErr THEN
                    Err := ICGetPref
                      (
                        (*inst :=*) InternetConfig,
                        (*key :=*) ADR(EntryName),
                        (*@attr :=*) EntryAttributes,
                        (*buf :=*) Dest,
                        (*@size :=*) EntrySize
                      );
                    IgnoreComponentResult(ICEnd(InternetConfig))
                END (*IF*);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            RETURN
                Err
        END GetConfigEntryValue;

        PROCEDURE SetConfigEntryValue
          (
            VAR TheToken : AEToken;
            VAR Src : AEDesc;
            RefCon : RefConType
          ) : OSErr;
          (* set-data routine to set a new value for a configuration entry. *)

            VAR
                EntryName : Str255;
                EntryAttributes : ICAttr;
                EntrySize : Size;
                SrcPtr : ADDRESS;

        BEGIN
            LOOP (*once*)
                GetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntryNameFieldID,
                    (*DesiredType :=*) TypeBlob,
                    (*@Dst :=*) EntryName,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                GetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntryAttributesFieldID,
                    (*DesiredType :=*) TypeEntryAttributes,
                    (*@Dst :=*) EntryAttributes,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                IF Src.dataHandle <> NIL THEN
                    EntrySize := GetHandleSize(Src.dataHandle);
                    HLock(Src.dataHandle);
                    SrcPtr := Src.dataHandle^
                ELSE
                    EntrySize := 0;
                    SrcPtr := NIL
                END (*IF*);
                Err := ICBegin(InternetConfig, ICTypes.icReadWritePerm);
                IF Err = noErr THEN
                    Err := ICSetPref
                      (
                        (*inst :=*) InternetConfig,
                        (*key :=*) ADR(EntryName),
                        (*@attr :=*) EntryAttributes,
                        (*buf :=*) SrcPtr,
                        (*size :=*) EntrySize
                      );
                    IgnoreComponentResult(ICEnd(InternetConfig))
                END (*IF*);
                IF Src.dataHandle <> NIL THEN
                    HUnlock(Src.dataHandle)
                END (*IF*);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            RETURN
                Err
        END SetConfigEntryValue;

        PROCEDURE AccessConfigEntryValue
          (
            DesiredClass : DescType;
            VAR Container : AEDesc;
            ContainerClass : DescType;
            KeyForm : DescType;
            VAR KeyData : AEDesc;
            VAR TheToken : AEDesc;
            TheRefCon : RefConType
          ) : OSErr;
          (* returns a token for the value property of a configuration entry. *)

            VAR
                EntryName : Str255;
                EntrySize : Size;
                EntryAttributes : ICAttr;

        BEGIN
            LOOP (*once*)
                GetPrivateDataField
                  (
                    (*@TheToken :=*) Container,
                    (*FieldID :=*) EntryNameFieldID,
                    (*DesiredType :=*) TypeBlob,
                    (*@Dst :=*) EntryName,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                GetPrivateDataField
                  (
                    (*@TheToken :=*) Container,
                    (*FieldID :=*) EntrySizeFieldID,
                    (*DesiredType :=*) AppleEvents.typeLongInteger,
                    (*@Dst :=*) EntrySize,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                GetPrivateDataField
                  (
                    (*@TheToken :=*) Container,
                    (*FieldID :=*) EntryAttributesFieldID,
                    (*DesiredType :=*) TypeEntryAttributes,
                    (*@Dst :=*) EntryAttributes,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                CreateAEToken
                  (
                    (*TheCleanup :=*) NoCleanupList,
                    (*@Result :=*) TheToken,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntryNameFieldID,
                    (*DataType :=*) TypeBlob,
                    (*@Src :=*) EntryName,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntrySizeFieldID,
                    (*DataType :=*) AppleEvents.typeLongInteger,
                    (*@Src :=*) EntrySize,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntryAttributesFieldID,
                    (*DataType :=*) TypeEntryAttributes,
                    (*@Src :=*) EntryAttributes,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetDataTypeField
                  (
                    (*@TheToken :=*) TheToken,
                    (*DataType :=*) TypeBlob,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetDataSizeField
                  (
                    (*@TheToken :=*) TheToken,
                    (*DataSize :=*) EntrySize,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetGetDataRoutineField
                  (
                    (*@TheToken :=*) TheToken,
                    (*GetData :=*) GetConfigEntryValue,
                    (*RefCon :=*) NIL,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                IF GetStateVariableState(ChangesAllowed) <> 0 THEN
                    SetSetDataRoutineField
                      (
                        (*@TheToken :=*) TheToken,
                        (*SetData :=*) SetConfigEntryValue,
                        (*RefCon :=*) NIL,
                        (*@Err :=*) Err
                      );
                    IF Err <> noErr THEN
                        EXIT
                    END (*IF*)
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            RETURN
                Err
        END AccessConfigEntryValue;

        PROCEDURE AccessConfigEntryAttribute
          (
            DesiredClass : DescType;
            VAR Container : AEDesc;
            ContainerClass : DescType;
            KeyForm : DescType;
            VAR KeyData : AEDesc;
            VAR TheToken : AEDesc;
            BitNr : LONGCARD
          ) : OSErr;
          (* returns a token for an attribute property of a configuration entry. *)

            VAR
                EntryAttributes : ICAttr;
                BitIsSet : BOOLEAN;

        BEGIN
            InitAEDesc(TheToken);
            LOOP (*once*)
                GetPrivateDataField
                  (
                    (*@TheToken :=*) Container,
                    (*FieldID :=*) EntryAttributesFieldID,
                    (*DesiredType :=*) TypeEntryAttributes,
                    (*@Dst :=*) EntryAttributes,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                BitIsSet := VAL(CARDINAL, BitNr) IN EntryAttributes;
                CreateAEToken
                  (
                    (*TheCleanup :=*) NoCleanupList,
                    (*@Result :=*) TheToken,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*DataType :=*) AppleEvents.typeBoolean,
                    (*@Src :=*) BitIsSet,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                AddCompareProc
                  (
                    (*@TheToken :=*) TheToken,
                    (*Operator :=*) AppleEvents.typeWildCard,
                    (*Compare :=*) AEObjectUseful.CompareBinary,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            RETURN
                Err;
        END AccessConfigEntryAttribute;

        PROCEDURE DeleteConfigEntry
          (
            VAR TheAppleEvent : AppleEvent;
            VAR Reply : AppleEvent;
            HandlerRefCon : RefConType
          ) : OSErr;
          (* deletes an entry from the configuration database. *)

            VAR
                Victim : AEToken;
                EntryName : Str255;

        BEGIN
            LOOP (*once*)
                IF GetStateVariableState(ChangesAllowed) = 0 THEN
                    Err := Errors.afpAccessDenied;
                    EXIT
                END (*IF*);
                GetCurrentToken(Victim);
                GetPrivateDataField
                  (
                    (*@TheToken :=*) Victim,
                    (*FieldID :=*) EntryNameFieldID,
                    (*DesiredType :=*) TypeBlob,
                    (*@Dst :=*) EntryName,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                Err := ICBegin(InternetConfig, ICTypes.icReadWritePerm);
                IF Err = noErr THEN
                    Err := ICDeletePref
                      (
                        (*inst :=*) InternetConfig,
                        (*key :=*) ADR(EntryName)
                      );
                    IgnoreComponentResult(ICEnd(InternetConfig))
                END (*IF*);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            RETURN
                Err
        END DeleteConfigEntry;

        PROCEDURE AccessConfigEntry
          (
            DesiredClass : DescType;
            VAR Container : AEDesc;
            ContainerClass : DescType;
            KeyForm : DescType;
            VAR KeyData : AEDesc;
            VAR TheToken : AEDesc;
            TheRefCon : RefConType
          ) : OSErr;
          (* returns a token for a configuration entry. *)

            VAR
                MatchName : Str255;
                MatchIndex : LONGINT;
                EntryAttributes : ICAttr;
                EntrySize : Size;
                EntryObjectDescriptor : AEDesc;

        BEGIN
            InitAEDesc(EntryObjectDescriptor);
            InitAEDesc(TheToken);
            LOOP (*once*)
                IF KeyForm = AEObjects.formName THEN
                    CoerceToString
                      (
                        (*@TheDesc :=*) KeyData,
                        (*@Result :=*) MatchName,
                        (*@Err :=*) Err
                      )
                ELSIF KeyForm = AEObjects.formAbsolutePosition THEN
                    CoerceToBlock
                      (
                        (*@TheDesc :=*) KeyData,
                        (*ToType :=*) AppleEvents.typeLongInteger,
                        (*@ToData :=*) MatchIndex,
                        (*@Err :=*) Err
                      );
                    IF Err <> noErr THEN
                        EXIT
                    END (*IF*);
                    Err := ICBegin(InternetConfig, ICTypes.icReadOnlyPerm);
                    IF Err = noErr THEN
                        Err := ICGetIndPref
                          (
                            (*inst :=*) InternetConfig,
                            (*n :=*) MatchIndex,
                            (*@key :=*) MatchName
                          );
                        IgnoreComponentResult(ICEnd(InternetConfig))
                    END (*IF*)
                ELSE
                    Err := AppleEvents.errAEEventNotHandled
                END (*IF*);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                EntrySize := 0;
                Err := ICBegin(InternetConfig, ICTypes.icReadOnlyPerm);
                IF Err = noErr THEN
                    Err := ICGetPref
                      (
                        (*inst :=*) InternetConfig,
                        (*key :=*) ADR(MatchName),
                        (*@attr :=*) EntryAttributes,
                        (*buf :=*) NIL,
                        (*@size :=*) EntrySize
                      );
                    IgnoreComponentResult(ICEnd(InternetConfig))
                END (*IF*);
                IF Err = ICTypes.icTruncatedErr THEN
                    Err := noErr
                ELSIF Err = ICTypes.icPrefNotFoundErr THEN
                    Err := AEObjects.errAENoSuchObject
                END (*IF*);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                CreateAEToken
                  (
                    (*TheCleanup :=*) NoCleanupList,
                    (*@Result :=*) TheToken,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntryNameFieldID,
                    (*DataType :=*) TypeBlob,
                    (*@Src :=*) MatchName,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntrySizeFieldID,
                    (*DataType :=*) AppleEvents.typeLongInteger,
                    (*@Src :=*) EntrySize,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetPrivateDataField
                  (
                    (*@TheToken :=*) TheToken,
                    (*FieldID :=*) EntryAttributesFieldID,
                    (*DataType :=*) TypeEntryAttributes,
                    (*@Src :=*) EntryAttributes,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                AddPropertyAccessorProc
                  (
                    (*@TheToken :=*) TheToken,
                    (*PropertyID :=*) AERegistry.pName,
                    (*Access :=*) AccessConfigEntryName,
                    (*RefCon :=*) NIL,
                    (*@Err :=*) Err
                  );
                AddPropertyAccessorProc
                  (
                    (*@TheToken :=*) TheToken,
                    (*PropertyID :=*) ValuePropertyID,
                    (*Access :=*) AccessConfigEntryValue,
                    (*RefCon :=*) NIL,
                    (*@Err :=*) Err
                  );
                AddPropertyAccessorProc
                  (
                    (*@TheToken :=*) TheToken,
                    (*PropertyID :=*) LockedPropertyID,
                    (*Access :=*) CAST(AccessorProc, AccessConfigEntryAttribute),
                    (*RefCon :=*) ICTypes.ICattrLockedBit,
                    (*@Err :=*) Err
                  );
                AddPropertyAccessorProc
                  (
                    (*@TheToken :=*) TheToken,
                    (*PropertyID :=*) VolatilePropertyID,
                    (*Access :=*) CAST(AccessorProc, AccessConfigEntryAttribute),
                    (*RefCon :=*) ICTypes.ICattrVolatileBit,
                    (*@Err :=*) Err
                  );
                AddAEHandlerProc
                  (
                    (*@TheToken :=*) TheToken,
                    (*EventClass :=*) AERegistry.kAECoreSuite,
                    (*EventID :=*) AERegistry.kAEDelete,
                    (*Handler :=*) DeleteConfigEntry,
                    (*HandlerRefCon :=*) NIL,
                    (*@Err :=*) Err
                  );
                CreateEntryDescriptor
                  (
                    (*@EntryName :=*) MatchName,
                    (*@ObjectDescriptor :=*) EntryObjectDescriptor
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                SetObjectDescriptor
                  (
                    (*@TheToken :=*) TheToken,
                    (*ObjectClass :=*) ClassConfigEntry,
                    (*@ObjectDescriptor :=*) EntryObjectDescriptor,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*);
            IF Err <> noErr THEN
                DisposeAEToken(TheToken)
            END (*IF*);
            DisposeAEDesc(EntryObjectDescriptor);
            RETURN
                Err
        END AccessConfigEntry;

        PROCEDURE CreateConfigEntry
          (
            VAR Reference : AEToken;
            Position : DescType;
            ObjectClass : DescType;
            VAR InitialData : AEDesc;
            VAR InitialProperties : AERecord;
            VAR ResultObjectSpecifier : AEDesc;
            RefCon : RefConType
          ) : OSErr;
          (* adds a new entry to the configuration database. *)

            VAR
                EntryName : Str255;
                EntryAttributes : ICAttr;
                EntryData : AEDesc;
                SrcPtr : ADDRESS;
                EntrySize : Size;

            PROCEDURE GetAttribute
              (
                FieldID : AEKeyword;
                BitNr : CARDINAL
              );

            BEGIN
                IF
                    GetBoolArg
                      (
                        (*@TheAppleEvent :=*) InitialProperties,
                        (*ArgKeyword :=*) FieldID,
                        (*Default :=*) FALSE,
                        (*@Err :=*) Err
                      )
                THEN
                    INCL(EntryAttributes, BitNr)
                END (*IF*);
            END GetAttribute;

        BEGIN (*CreateConfigEntry*)
            InitAEDesc(EntryData);
            LOOP (*once*)
                IF GetStateVariableState(ChangesAllowed) = 0 THEN
                    Err := Errors.afpAccessDenied;
                    EXIT
                END (*IF*);
                GetStringArg
                  (
                    (*@TheAppleEvent :=*) InitialProperties,
                    (*ArgKeyword :=*) AERegistry.pName,
                    (*@TheArg :=*) EntryName,
                    (*@Err :=*) Err
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* check entry doesn't already exist *)
                Err := ICBegin(InternetConfig, ICTypes.icReadOnlyPerm);
                IF Err = noErr THEN
                    Err := ICGetPref
                      (
                        (*inst :=*) InternetConfig,
                        (*key :=*) ADR(EntryName),
                        (*@attr :=*) EntryAttributes,
                        (*buf :=*) NIL,
                        (*@size :=*) EntrySize
                      );
                    IgnoreComponentResult(ICEnd(InternetConfig))
                END (*IF*);
                IF Err = ICTypes.icPrefNotFoundErr THEN
                    Err := noErr
                ELSIF Err = noErr THEN
                    Err := Errors.afpObjectExists
                END (*IF*);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                EntryAttributes := ICAttr{};
              (* Doesn't actually make sense to allow setting any attributes *)
              (* GetAttribute(LockedPropertyID, ICTypes.ICattrLockedBit); *)
              (* GetAttribute(VolatilePropertyID, ICTypes.ICattrVolatileBit); *)
                Err := AEGetKeyDesc
                  (
                    (*@theAERecord :=*) InitialProperties,
                    (*theAEKeyword :=*) ValuePropertyID,
                    (*desiredType :=*) TypeBlob,
                    (*@result :=*) EntryData
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                IF EntryData.dataHandle <> NIL THEN
                    EntrySize := GetHandleSize(EntryData.dataHandle);
                    HLock(EntryData.dataHandle);
                    SrcPtr := EntryData.dataHandle^
                ELSE
                    EntrySize := 0;
                    SrcPtr := NIL
                END (*IF*);
                Err := ICBegin(InternetConfig, ICTypes.icReadWritePerm);
                IF Err = noErr THEN
                    Err := ICSetPref
                      (
                        (*inst :=*) InternetConfig,
                        (*key :=*) ADR(EntryName),
                        (*@attr :=*) EntryAttributes,
                        (*buf :=*) SrcPtr,
                        (*size :=*) EntrySize
                      );
                    IgnoreComponentResult(ICEnd(InternetConfig))
                END (*IF*);
                IF EntryData.dataHandle <> NIL THEN
                    HUnlock(EntryData.dataHandle)
                END (*IF*);
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                CreateEntryDescriptor
                  (
                    (*@EntryName :=*) EntryName,
                    (*@ObjectDescriptor :=*) ResultObjectSpecifier
                  );
              (* all done *)
                EXIT
            END (*LOOP*);
            DisposeAEDesc(EntryData);
            RETURN
                Err
        END CreateConfigEntry;

        PROCEDURE CountConfigEntries
          (
            DesiredType : DescType;
            ContainerClass : DescType;
            VAR Container : AEDesc;
            VAR Result : LONGCARD
          ) : OSErr;
          (* returns the number of configuration entries. *)

        BEGIN
            Err := ICBegin(InternetConfig, ICTypes.icReadOnlyPerm);
            IF Err = noErr THEN
                Err := ICCountPref(InternetConfig, Result);
                IgnoreComponentResult(ICEnd(InternetConfig))
            END (*IF*);
            RETURN
                Err
        END CountConfigEntries;

        PROCEDURE InitAEHandling;
          (* installs my AppleEvent-related handlers. *)

            VAR
                NullDescriptor : AEDesc;

            PROCEDURE InstallAEHandler
              (
                TheEventClass : AEEventClass;
                TheEventID : AEEventID;
                TheHandler : AEHandlerProc
              );

            BEGIN
                Err := AEInstallEventHandler
                  (
                    (*theAEEventClass :=*) TheEventClass,
                    (*theAEEventID :=*) TheEventID,
                    (*handler :=*) TheHandler,
                    (*handlerRefcon :=*) NIL,
                    (*isSysHandler :=*) FALSE
                  )
            END InstallAEHandler;

            PROCEDURE InstallPtrCoercionHandler
              (
                FromType, ToType : DescType;
                TheHandler : PtrCoercionHandler
              );

            BEGIN
                Err := AEInstallPtrCoercionHandler
                  (
                    (*fromType :=*) FromType,
                    (*toType :=*) ToType,
                    (*handler :=*) TheHandler,
                    (*handlerRefcon :=*) NIL,
                    (*fromTypeIsDesc :=*) FALSE,
                    (*isSysHandler :=*) FALSE
                  )
            END InstallPtrCoercionHandler;

            PROCEDURE InstallDescCoercionHandler
              (
                FromType, ToType : DescType;
                TheHandler : DescCoercionHandler
              );

            BEGIN
                Err := AEInstallDescCoercionHandler
                  (
                    (*fromType :=*) FromType,
                    (*toType :=*) ToType,
                    (*handler :=*) TheHandler,
                    (*handlerRefcon :=*) NIL,
                    (*fromTypeIsDesc :=*) TRUE,
                    (*isSysHandler :=*) FALSE
                  )
            END InstallDescCoercionHandler;

        BEGIN (*InitAEHandling*)
            InitAEDesc(NullDescriptor);
            Err := AEObjectInit();
            InstallAEHandler
              (
                (*TheEventClass :=*) AppleEvents.kCoreEventClass,
                (*TheEventID :=*) AppleEvents.kAEOpenApplication,
                (*TheHandler :=*) HandleOpenApplicationEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) AppleEvents.kCoreEventClass,
                (*TheEventID :=*) AppleEvents.kAEQuitApplication,
                (*TheHandler :=*) HandleQuitEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) AERegistry.kAECoreSuite,
                (*TheEventID :=*) AERegistry.kAEGetData,
                (*TheHandler :=*) AEObjectUseful.HandleGetDataEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) AERegistry.kAECoreSuite,
                (*TheEventID :=*) AERegistry.kAEGetDataSize,
                (*TheHandler :=*) AEObjectUseful.HandleGetDataSizeEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) AERegistry.kAECoreSuite,
                (*TheEventID :=*) AERegistry.kAECountElements,
                (*TheHandler :=*) AEObjectUseful.HandleCountElementsEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) AERegistry.kAECoreSuite,
                (*TheEventID :=*) AERegistry.kAESetData,
                (*TheHandler :=*) AEObjectUseful.HandleSetDataEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) AERegistry.kAECoreSuite,
                (*TheEventID :=*) AERegistry.kAEDoObjectsExist,
                (*TheHandler :=*) AEObjectUseful.HandleExistsEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) AERegistry.kAECoreSuite,
                (*TheEventID :=*) AERegistry.kAEDelete,
                (*TheHandler :=*) AEObjectUseful.DispatchEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) AERegistry.kAECoreSuite,
                (*TheEventID :=*) AERegistry.kAECreateElement,
                (*TheHandler :=*) AEObjectUseful.HandleCreateElementEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) AERegistry.kAEAbout,
                (*TheHandler :=*) HandleAboutEvent
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) ScramblePasswordEventID,
                (*TheHandler :=*) HandleScramblePassword
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) UnscramblePasswordEventID,
                (*TheHandler :=*) HandleScramblePassword
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) ConvertFromPStringBlobID,
                (*TheHandler :=*) ConvertFromPStringBlob
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) ConvertToPStringBlobID,
                (*TheHandler :=*) ConvertToPStringBlob
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) ConvertFromTextBlobID,
                (*TheHandler :=*) ConvertFromTextBlob
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) ConvertToTextBlobID,
                (*TheHandler :=*) ConvertToTextBlob
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) ConvertFromStringListBlobID,
                (*TheHandler :=*) ConvertFromStringListBlob
              );
            InstallAEHandler
              (
                (*TheEventClass :=*) MySignature,
                (*TheEventID :=*) ConvertToStringListBlobID,
                (*TheHandler :=*) ConvertToStringListBlob
              );
            Err := AESetObjectCallbacks
              (
                (*myCompareProc :=*) AEObjectUseful.CompareObjects,
                (*myCountProc :=*) AEObjectUseful.CountElements,
                (*myDisposeTokenProc :=*) AEObjectUseful.DisposeAEToken,
                (*myGetMarkTokenProc :=*) AEObjects.noGetMarkTokenProc,
                (*myMarkProc :=*) AEObjects.noMarkProc,
                (*myAdjustMarksProc :=*) AEObjects.noAdjustMarksProc,
                (*myGetErrDescProc :=*) AEObjects.noGetErrDescProc
              );
            Err := AEInstallObjectAccessor
              (
                (*desiredClass :=*) AppleEvents.typeWildCard,
                (*containerType :=*) AppleEvents.typeWildCard,
                (*theAccessor :=*) AEObjectUseful.AccessObject,
                (*accessorRefcon :=*) NIL,
                (*isSysHandler :=*) FALSE
              );
            CreateAEToken
              (
                (*TheCleanup :=*) NoCleanupList,
                (*@Result :=*) AppToken,
                (*@Err :=*) Err
              );
            SetObjectDescriptor
              (
                (*@TheToken :=*) AppToken,
                (*ObjectClass :=*) AERegistry.cApplication,
                (*@ObjectDescriptor :=*) NullDescriptor,
                (*@Err :=*) Err
              );
            AddCountProc
              (
                (*@TheToken :=*) AppToken,
                (*DesiredType :=*) ClassConfigEntry,
                (*Count :=*) CAST(CountProc, CountConfigEntries),
                (*@Err :=*) Err
              );
            AddPropertyAccessorProc
              (
                (*@TheToken :=*) AppToken,
                (*PropertyID :=*) AERegistry.pVersion,
                (*Access :=*) AccessVersionProperty,
                (*RefCon :=*) NIL,
                (*@Err :=*) Err
              );
            AddPropertyAccessorProc
              (
                (*@TheToken :=*) AppToken,
                (*PropertyID :=*) SeedPropertyID,
                (*Access :=*) AccessSeedProperty,
                (*RefCon :=*) NIL,
                (*@Err :=*) Err
              );
            AddPropertyAccessorProc
              (
                (*@TheToken :=*) AppToken,
                (*PropertyID :=*) ChangesAllowedPropertyID,
                (*Access :=*) CAST(AccessorProc, AccessGlobalStateProperty),
                (*RefCon :=*) ADR(ChangesAllowed),
                (*@Err :=*) Err
              );
            AddPropertyAccessorProc
              (
                (*@TheToken :=*) AppToken,
                (*PropertyID :=*) ScramblingAllowedPropertyID,
                (*Access :=*) CAST(AccessorProc, AccessGlobalStateProperty),
                (*RefCon :=*) ADR(ScramblingAllowed),
                (*@Err :=*) Err
              );
            AddAccessorProc
              (
                (*@TheToken :=*) AppToken,
                (*DesiredClass :=*) ClassConfigEntry,
                (*Access :=*) AccessConfigEntry,
                (*RefCon :=*) NIL,
                (*@Err :=*) Err
              );
            AddElementCreatorRoutine
              (
                (*@TheToken :=*) AppToken,
                (*ObjectClass :=*) ClassConfigEntry,
                (*CreateElement :=*) CreateConfigEntry,
                (*RefCon :=*) NIL,
                (*@Err :=*) Err
              );
        END InitAEHandling;

    END AEHandling;

(*
    Menu handling
*)

    MODULE MenuHandling;

        FROM SYSTEM IMPORT
            ADDRESS,
            CAST;
        FROM Types IMPORT
            ShortCard;
        FROM Menus IMPORT
            MenuHandle,
            CheckItem,
            GetMenu;
        IMPORT
            AppleEvents;
        IMPORT
            AERegistry;
        FROM CommandHandler IMPORT
            Command,
            CommandAction,
            StateHiliteAction,
            StateVariable,
            AddStateHiliteAction,
            DisposeCommand,
            GetStateVariableState,
            NewCommand,
            SetStateVariableState;
        FROM MenuHandler IMPORT
            Menu,
            DefaultMenuBar,
            AttachMenuToMenuBar,
            DisposeMenu,
            NewMenu,
            RefreshMenuBar,
            SetMenuCommand,
            SetupAppleMenu;
        IMPORT
            MySignature,
            ChangesAllowed,
            Err,
            QuitCommand,
            ScramblingAllowed,
            SendMyselfSimpleEvent;

        EXPORT
            SetupMenus;

        VAR
            OptionsMenu : MenuHandle;
        CONST
          (* IDs of items in Options menu *)
            ChangesAllowedItemID = 1;
            ScramblingAllowedItemID = 2;

        PROCEDURE HandleAboutCommand
          (
            Unused : ADDRESS
          );
          (* requests display of my about box. *)

        BEGIN
            SendMyselfSimpleEvent
              (
                (*TheAEEventClass :=*) MySignature,
                (*TheAEEventID :=*) AERegistry.kAEAbout
              )
        END HandleAboutCommand;

        PROCEDURE HandleQuitCommand
          (
            Unused : ADDRESS
          );
          (* requests the application to quit. *)

        BEGIN
            SendMyselfSimpleEvent
              (
                (*TheAEEventClass :=*) AppleEvents.kCoreEventClass,
                (*TheAEEventID :=*) AppleEvents.kAEQuitApplication
              )
        END HandleQuitCommand;

        PROCEDURE TrackState
          (
            HiliteIndex : ShortCard;
            Hilite : BOOLEAN;
            ItemIndex : LONGCARD
          );
          (* state variable state-change action which checks/unchecks
            corresponding menu item. *)

        BEGIN
            CheckItem(OptionsMenu, ItemIndex, Hilite)
        END TrackState;

        PROCEDURE ToggleState
          (
            TheState : StateVariable
          );
          (* command action which toggles the state of the specified
            state variable. *)

        BEGIN
            SetStateVariableState
              (
                (*OfState :=*) TheState,
                (*NewState :=*) 1 - GetStateVariableState(TheState)
              )
        END ToggleState;

        PROCEDURE SetupMenus;
          (* sets up my menus and associated handlers. *)

            VAR
                ThisMenu : Menu;
                ThisCommand : Command;

        BEGIN
          (* set up Apple menu *)
            NewMenu(GetMenu(128), ThisMenu, Err);
            SetupAppleMenu(ThisMenu, Err);
            NewCommand
              (
                (*Action :=*) HandleAboutCommand,
                (*ActionArg :=*) NIL,
                (*Enabled :=*) TRUE,
                (*@Result :=*) ThisCommand,
                (*@Err :=*) Err
              );
            SetMenuCommand
              (
                (*InMenu :=*) ThisMenu,
                (*ItemID :=*) 1,
                (*TheCommand :=*) ThisCommand,
                (*@Err :=*) Err
              );
            DisposeCommand(ThisCommand);
            AttachMenuToMenuBar(ThisMenu, DefaultMenuBar, Err);
            DisposeMenu(ThisMenu);
          (* set up File menu *)
            NewMenu(GetMenu(129), ThisMenu, Err);
            NewCommand
              (
                (*Action :=*) HandleQuitCommand,
                (*ActionArg :=*) NIL,
                (*Enabled :=*) TRUE,
                (*@Result :=*) QuitCommand,
                (*@Err :=*) Err
              );
            SetMenuCommand
              (
                (*InMenu :=*) ThisMenu,
                (*ItemID :=*) 1,
                (*TheCommand :=*) QuitCommand,
                (*@Err :=*) Err
              );
            AttachMenuToMenuBar(ThisMenu, DefaultMenuBar, Err);
            DisposeMenu(ThisMenu);
          (* set up Options menu *)
            OptionsMenu := GetMenu(130);
            NewMenu(OptionsMenu, ThisMenu, Err);
            NewCommand
              (
                (*Action :=*) CAST(CommandAction, ToggleState),
                (*ActionArg :=*) CAST(ADDRESS, ChangesAllowed),
                (*Enabled :=*) TRUE,
                (*@Result :=*) ThisCommand,
                (*@Err :=*) Err
              );
            SetMenuCommand
              (
                (*InMenu :=*) ThisMenu,
                (*ItemID :=*) ChangesAllowedItemID,
                (*TheCommand :=*) ThisCommand,
                (*@Err :=*) Err
              );
            AddStateHiliteAction
              (
                (*ToState :=*) ChangesAllowed,
                (*Hilite :=*) CAST(StateHiliteAction, TrackState),
                (*HiliteIndex :=*) 1,
                (*HiliteArg :=*) ChangesAllowedItemID,
                (*@Err :=*) Err
              );
            NewCommand
              (
                (*Action :=*) CAST(CommandAction, ToggleState),
                (*ActionArg :=*) CAST(ADDRESS, ScramblingAllowed),
                (*Enabled :=*) TRUE,
                (*@Result :=*) ThisCommand,
                (*@Err :=*) Err
              );
            SetMenuCommand
              (
                (*InMenu :=*) ThisMenu,
                (*ItemID :=*) ScramblingAllowedItemID,
                (*TheCommand :=*) ThisCommand,
                (*@Err :=*) Err
              );
            AddStateHiliteAction
              (
                (*ToState :=*) ScramblingAllowed,
                (*Hilite :=*) CAST(StateHiliteAction, TrackState),
                (*HiliteIndex :=*) 1,
                (*HiliteArg :=*) ScramblingAllowedItemID,
                (*@Err :=*) Err
              );
            AttachMenuToMenuBar(ThisMenu, DefaultMenuBar, Err);
            DisposeMenu(ThisMenu);
          (* done all menus *)
            RefreshMenuBar
        END SetupMenus;

    END MenuHandling;

(*
    Mainline
*)

    MODULE Mainline;

        FROM SYSTEM IMPORT
            ADDRESS;
        FROM Types IMPORT
            noErr;
        FROM Resources IMPORT
            CurResFile;
        FROM QuickDraw IMPORT
            OpenPortVar;
        IMPORT
            Components;
        FROM Useful IMPORT
            FinitToolbox,
            IgnoreComponentResult,
            InitToolbox;
        FROM Compatibility IMPORT
            AppleEventsPresent,
            GestaltSelectorPresent;
        FROM AEUseful IMPORT
            InitAEDesc;
        FROM CommandHandler IMPORT
            NewStateVariable;
        FROM EventHandler IMPORT
            EventLoop,
            FinitEventHandlers,
            InitEventHandlers,
            InstallQuitCheck;
        FROM MenuHandler IMPORT
            FinitMenuHandling,
            InitMenuHandling;
        FROM ICCAPI IMPORT
            ICFindConfigFile,
            ICStart,
            ICStop;
        IMPORT
            MySignature,
            NeedAppleScriptIndex,
            NeedInternetConfigIndex,
            AppResFile,
            ChangesAllowed,
            CurrentReply,
            DefaultPort,
            Err,
            InternetConfig,
            Quitting,
            ScramblingAllowed,
            DisplayErrorMessageIndex,
            InitAEHandling,
            SetupMenus;

        PROCEDURE CanRun() : BOOLEAN;
          (* is this system fit for me to run. *)

            VAR
                ICan : BOOLEAN;

        BEGIN
            ICan := FALSE; (* initial assumption *)
            LOOP (*once*)
                IF NOT AppleEventsPresent() THEN
                    DisplayErrorMessageIndex(NeedAppleScriptIndex);
                    EXIT
                END (*IF*);
                IF NOT GestaltSelectorPresent(Components.gestaltComponentMgr) THEN
                    DisplayErrorMessageIndex(NeedAppleScriptIndex);
                    EXIT
                END (*IF*);
                IF ICStart(InternetConfig, MySignature) <> noErr THEN
                    DisplayErrorMessageIndex(NeedInternetConfigIndex);
                    EXIT
                END (*IF*);
              (* passed all checks: *)
                ICan := TRUE;
                EXIT
            END (*LOOP*);
            RETURN
                ICan
        END CanRun;

        PROCEDURE CanQuit
          (
            Unused : ADDRESS
          ) : BOOLEAN;
          (* am I ready to quit. *)

        BEGIN
            RETURN
                Quitting
        END CanQuit;

        PROCEDURE Initialize;

        BEGIN
            LOOP (*once*)
                NewStateVariable
                  (
                    (*NrStates :=*) 1,
                    (*InitialState :=*) 0,
                    (*Enabled :=*) TRUE,
                    (*@Result :=*) ChangesAllowed,
                    (*@Err :=*) Err
                  );
                NewStateVariable
                  (
                    (*NrStates :=*) 1,
                    (*InitialState :=*) 0,
                    (*Enabled :=*) TRUE,
                    (*@Result :=*) ScramblingAllowed,
                    (*@Err :=*) Err
                  );
                Err := ICFindConfigFile
                  (
                    (*inst :=*) InternetConfig,
                    (*count :=*) 0,
                    (*folders :=*) NIL
                  );
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                InitEventHandlers(TRUE, Err);
                InitMenuHandling(TRUE, TRUE, Err);
                InstallQuitCheck(CanQuit, NIL, Err);
                SetupMenus;
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
                InitAEHandling;
                IF Err <> noErr THEN
                    EXIT
                END (*IF*);
              (* all done *)
                EXIT
            END (*LOOP*)
        END Initialize;

        PROCEDURE Finalize;

        BEGIN
            FinitMenuHandling;
            FinitEventHandlers
        END Finalize;

    BEGIN (*Mainline*)
        InitToolbox;
        AppResFile := CurResFile();
        OpenPortVar(DefaultPort);
        Quitting := FALSE;
        InitAEDesc(CurrentReply);
        InternetConfig := NIL;
        LOOP (*once*)
            IF NOT CanRun() THEN
                EXIT
            END (*IF*);
            Initialize;
            IF Err <> noErr THEN
                EXIT
            END (*IF*);
            EventLoop;
          (* all done *)
            EXIT
        END (*LOOP*);
        IF InternetConfig <> NIL THEN
            IgnoreComponentResult(ICStop(InternetConfig))
        END (*IF*);
        Finalize;
        FinitToolbox
    END Mainline;

END InternetConfigAccess.